vb中如何用circle方法绘制太极八卦图

首先你要明白太极的阴阳鱼是怎么样标准的画出来的~

说白了,阴阳鱼就是一黑一白两个圆形边贴着边,围着这两个圆的接触点同向转动的运动轨迹,阴阳鱼眼就是这个两个圆形放大了的圆心~

下边是我的代码,可能有些繁琐,不过你能看懂过程就最好了~
需要额外添加一个timer控件,在form_load以后一段时间你会看到阴阳鱼的形成过程,然后太极图就会转起来~

option explicit

dim pi as double'π值
dim centerpointx as long'两个圆围绕旋转的圆心x
dim centerpointy as long'两个圆围绕旋转的圆心y

dim tempx1 as long'第一个圆的圆心x
dim tempy1 as long'第一个圆的圆心y

dim tempx2 as long'第二个圆的圆心x
dim tempy2 as long'第二个圆的圆心y

dim radius as long'两个圆的半径,因为两个圆等大,所以就定义了一个变量
dim angle as double'旋转的角度

private sub form_load()

centerpointx = 4000'设置起始旋转点x
centerpointy = 4000'设置起始旋转点y
radius = 1000'半径为1000
angle = 0'起始旋转角为0

tempx1 = centerpointx'第一个圆的起始位置x
tempy1 = 4000 - radius'第一个圆的起始位置y

tempx2 = centerpointx'第二个圆的起始位置x
tempy2 = 4000 + radius'第二个圆的起始位置y

pi = 4 * atn(1)'给∏赋值,这里让机器计算出比较标准的值,3.**...

'下边初始化计时器
timer1.interval = 50
timer1.enabled = true

end sub

'下边是计时器过程
private sub timer1_timer()

me.fillstyle = 0'设置窗体的填充**,你可以改为别的值试下效果

me.fillcolor = vbblack'设置窗体的填充颜色,第一个圆为黑色
me.forecolor = vbblack'设置窗体的线条颜色,也为黑色
me.circle (tempx1, tempy1), radius'这里开始画第一个圆,circle函数的参数都是什么意思你明白吧?~
'下边画第一个阴阳鱼的"鱼眼"
me.fillcolor = vbwhite'因为第一个圆是黑色,所以"眼"画为白色
me.forecolor = vbwhite'见上边解释
me.circle (tempx1, tempy1), radius / 3'画一个稍小的圆

'同样,下边画第二个圆,白色
me.fillcolor = vbwhite
me.forecolor = vbwhite
me.circle (tempx2, tempy2), radius
'黑"鱼眼"
me.fillcolor = vbblack
me.forecolor = vbblack
me.circle (tempx2, tempy2), radius / 3

'---到这里第一次绘制完成了---
'---下边为下一次绘制做下准备-

angle = angle + 1'两个圆围绕旋转的角度加1
if angle > 360 then'大于360时,说明转了一整圈了,所以从0开始重新旋转
angle = 0
end if
'下边根据三角函数计算下一次两个圆的圆心位置,自己画个图看下吧~我懒,就不画了,^^
tempx1 = centerpointx + sin(angle * pi / 180) * radius
tempy1 = centerpointy - cos(angle * pi / 180) * radius
'第二个圆可以懒省事,不通过计算获取其圆心位置,因为其和第一个圆与围绕心是对称的,可以通过坐标转换来获取圆心位置
tempx2 = centerpointx - (tempx1 - centerpointx)
tempy2 = centerpointy + (centerpointy - tempy1)

'---到这里,一次绘制就完成了---

end sub

'希望你能看得懂~